# Temporary stuff (e.g., upstream bug fixes that haven't landed)
#
# self  - next package set (after our additions)
# super - prior package set (before our additions)
# pkgs  - final package set (after everyone's additions)
#

self: super: pkgs: with pkgs; {

  # igv java library LCD sub-pixel fron rendering results in missing characters
  igv = super.igv.overrideAttrs (attrs: {
    postFixup = attrs.postFixup or "" + ''
      wrapProgram $out/bin/igv --suffix _JAVA_OPTIONS ' ' -Dawt.useSystemAAFontSettings=on
    '';
    nativeBuildInputs = attrs.nativeBuildInputs or [] ++ [
      makeWrapper
    ];
  } );

  # https://github.com/NixOS/nixpkgs/issues/38459
  octave = super.octave.overrideAttrs (attrs: {
    buildInputs = attrs.buildInputs ++ [ gl2ps ];
  } );

  gl2ps = callPackage ./gl2ps.nix { };

  # https://github.com/NixOS/nixpkgs/issues/44426
  python27 = super.python27.override { packageOverrides = pythonOverrides; };
  python35 = super.python35.override { packageOverrides = pythonOverrides; };
  python36 = super.python36.override { packageOverrides = pythonOverrides; };
  python37 = super.python37.override { packageOverrides = pythonOverrides; };

  pythonOverrides = import ./python-packages.nix pkgs;

  # same for R as Python (except we have to do the self/super plumbing)
  rPackages = super.rPackages.override {
    overrides =
      let
        overrides = rOverrides self super.rPackages;
        self = super.rPackages // overrides;
      in
        overrides;
  };

  rOverrides = import ./r-modules.nix pkgs;
}