# Temporary stuff (e.g., upstream bug fixes that haven't landed)
#
# self  - next package set (after our additions)
# super - prior package set (before our additions)
# pkgs  - final package set (after everyone's additions)
#

self: super: pkgs: with pkgs; {

  # igv java library LCD sub-pixel fron rendering results in missing characters
  igv = super.igv.overrideAttrs (attrs: {
    postFixup = attrs.postFixup or "" + ''
      wrapProgram $out/bin/igv --suffix _JAVA_OPTIONS ' ' -Dawt.useSystemAAFontSettings=on
    '';
    nativeBuildInputs = attrs.nativeBuildInputs or [] ++ [
      makeWrapper
    ];
  } );

  # https://github.com/NixOS/nixpkgs/issues/92458 and https://github.com/NixOS/nixpkgs/pull/108709
  openblas = super.openblas.overrideAttrs (attrs: rec {
    version = "0.3.12";
    src = fetchFromGitHub {
      owner = "xianyi";
      repo = "OpenBLAS";
      rev = "v${version}";
      sha256 = "0mk1kjkr96bvvcq2zigzjrs0cnhwsf6gfi0855mp9yifn8lvp20y";
    };
    patches = [ ];
  } );

  # https://github.com/NixOS/nixpkgs/issues/44426
  python27 = super.python27.override { packageOverrides = pythonOverrides; };
  python36 = super.python36.override { packageOverrides = pythonOverrides; };
  python37 = super.python37.override { packageOverrides = pythonOverrides; };
  python38 = super.python38.override { packageOverrides = pythonOverrides; };
  python39 = super.python39.override { packageOverrides = pythonOverrides; };

  pythonOverrides = import ./python-packages.nix pkgs;

  # same for R as Python (except we have to do the self/super plumbing)
  rPackages = super.rPackages.override {
    overrides =
      let
        overrides = rOverrides self super.rPackages;
        self = super.rPackages // overrides;
      in
        overrides;
  };

  rOverrides = import ./r-modules.nix pkgs;
}