{ stdenv, fetchFromGitHub, which, autoconf, automake
, zlib, curl
, python, hexdump, sambamba, samblaster, samtools }:

stdenv.mkDerivation rec {
  version = "0.3.0";
  name = "lumpy-${version}";

  src = fetchFromGitHub {
    inherit name;
    owner = "arq5x";
    repo = "lumpy-sv";
    rev = version;
    fetchSubmodules = true;
    sha256 = "1r6sssbnz017jpnsfb6dfjj0y7bzxgxxdikz4rak569m6kqkawqq";
  };

  installPhase = ''
    mkdir -p "$out"
    cp -r bin "$out"
    substituteInPlace "$out/bin/lumpyexpress.config" \
      --replace "$PWD/" "$out"
    mkdir -p "$out/lib/lumpy/bamkit"
    for script in \
      pairend_distro.py \
      bamkit/bamgroupreads.py \
      bamkit/bamfilterrg.py \
      bamkit/bamlibs.py
    do
      cp "scripts/$script" "$out/lib/lumpy/$script"
      substituteInPlace "$out/bin/lumpyexpress.config" \
        --replace "$out/scripts/$script" "$out/lib/lumpy/$script"
    done
  '';

  buildInputs = [
    which
    autoconf
    automake
    zlib
    curl
    (python.withPackages (packages: with packages; [ numpy pysam ]))
    hexdump
    sambamba
    samblaster
    samtools
  ];

  meta = with stdenv.lib; {
    description = "A probabilistic framework for structural variant discovery.";
    homepage = https://github.com/arq5x/lumpy-sv;
    platforms = platforms.all;
    license = licenses.mit;
  };
}