diff --git a/meraculous.nix b/meraculous.nix
new file mode 100644
index 0000000..50db1a6
--- /dev/null
+++ b/meraculous.nix
@@ -0,0 +1,41 @@
+with import <nixpkgs> { };
+
+# gcc 5.x c++11 requires istream to be explicitly cast to bool
+
+let
+  stdenv49 = overrideCC stdenv gcc49;
+
+in stdenv49.mkDerivation rec {
+  version = "2.2.2.5_lt";
+  name = "meraculous-${version}";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/meraculous20/release-${version}.tgz";
+    sha256 = "1i0p46aidkqh9ah3ifgj8q70r24bd7c2x0b251fgsggbf1cwzrlb";
+  };
+
+  postPatch = ''
+    sed -ie '/^set(Boost_USE_STATIC/d' src/c/CMakeLists.txt
+  '';
+
+  postInstall = ''
+    wrapProgram $out/bin/run_meraculous.sh --prefix PERL5LIB ":" "$PERL5LIB"
+  '';
+
+  buildInputs = [
+    makeWrapper
+    gzip
+    cmake
+    (boost159.override { stdenv = stdenv49; })
+    perl
+    perlPackages.Log4Perl
+    gnuplot
+  ];
+
+  meta = with stdenv.lib; {
+    homepage = http://jgi.doe.gov/data-and-tools/meraculous;
+    description = "Meraculous is a whole genome assembler for Next Generation Sequencing data geared for large genomes.";
+    platforms = platforms.all;
+    license = licenses.bsd3;
+  };
+}