{ lib, config, pkgs, ... }: {
  nixpkgs.overlays = [(final: prev: rec {
    pythonPackagesExtensions = prev.pythonPackagesExtensions ++ [
      (
        python-final: python-prev: let
          py = python-prev;
        in {
          opencamlib = py.toPythonModule (pkgs.stdenv.mkDerivation rec {
            pname = "opencamlib";
            version = "2019.07";
            nativeBuildInputs = (with pkgs;[
              cmake
              git
              doxygen
              boost
              texlive.combined.scheme-full
            ]);
            propagatedNativeBuildInputs = [
              py.python
              py.boost
              py.vtk
            ];
            postPatch = ''
              mkdir -p $out/${py.python.sitePackages}/{lib,ocl}
              sed -e 's#LIBRARY DESTINATION ''${PYTHON_ARCH_PACKAGES}#LIBRARY DESTINATION '"$out"'/${py.python.sitePackages}#g' -i src/pythonlib/pythonlib.cmake
              sed -e 's#DESTINATION ''${PYTHON_SITE_PACKAGES}#DESTINATION '"$out"'/${py.python.sitePackages}#g' -i src/pythonlib/pythonlib.cmake
            '';
            cmakeFlags = [
              "-DVERSION_STRING=2019.07"
              "-DBUILD_CXX_LIB=ON"
              "-DBUILD_PY_LIB=ON"
              "-DUSE_PY_3=ON"
              "-DCMAKE_BUILD_TYPE=Release"
            ];
            src = pkgs.fetchFromGitHub {
              owner = "aewallin";
              repo = "opencamlib";
              rev = "2019.07";
              sha256 = "1a8pxp1mh8x3bfsb0l97vgxrpk482p7q9jprkd4m9hv69vva2bdz";
            };
          });
          equation = py.buildPythonPackage {
            pname = "Equation";
            version = "1.2.01";
            nativeBuildInputs = [
              py.setuptools
              py.numpy
            ];
            src = pkgs.fetchzip {
              url = "https://files.pythonhosted.org/packages/2e/cc/115fb1722051f99b9699864586e7f96ca0080645387698af922fade4f7b2/Equation-1.2.01.zip";
              sha256 = "YFxZB3vaC5s49K1AQLFF4WGUr2RpomJTLQdZ24ITXr4=";
            };
          };
          morphio = py.toPythonModule ( pkgs.stdenv.mkDerivation rec {
            pname = "MorphIO";
            version = "3.3.4";
            nativeBuildInputs = (with pkgs; [
              cmake
              ninja
              py.numpy
              hdf5
            ]);
            cmakeFlags = [
              "-DMorphIO_CXX_WARNINGS=OFF"
            ];
            postInstall = ''
              mkdir -p $out/${py.python.sitePackages}
              mv ../morphio $out/${py.python.sitePackages}
              cp binds/python/_morphio.* $out/${py.python.sitePackages}/morphio/
            '';
            src = pkgs.fetchFromGitHub {
              owner = "BlueBrain";
              repo = "MorphIO";
              rev = "v${version}";
              deepClone = true;
              fetchSubmodules = true;
              sha256 = "C3zDziG7LF7v22ZvplBrtOYq7iKGnAavfpiBCcShHaQ=";
            };
          });

        }
      )
    ];
    # Add CUDA Support to Blender
    blender_cuda = prev.blender.override {
      cudaSupport = true;
    };
    blender = final.blender_cuda.withPackages (p: with p; [
      # OpenCAMLib support
      shapely
      equation
      #opencamlib
      # NeuroMorphoVis support
      matplotlib
      seaborn
      pandas
      pillow
      h5py
      morphio
      # TODO add BluePy support?
    ]);
    # Update RX and Aseprite
    rx = prev.rx.overrideAttrs (old: {
      version = "git";
      src = prev.fetchFromGitHub {
        owner = "cloudhead";
        repo = old.pname;
        rev = "18625a68921873ebe21a7ea8096409a9f0314541";
        sha256 = "sha256-LTpaV/fgYUgA2M6Wz5qLHnTNywh13900g+umhgLvciM=";
      };
    });
  })];

  environment.systemPackages = with pkgs; [
    blender
    # GTK theme support (basic) for GTK apps e.g. inkscape
    adwaita-icon-theme

    rx
    aseprite-unfree
    gimp
    
    glaxnimate
    inkscape-with-extensions
  ];
}