{ lib, config, pkgs, ... }: let
  wiiUDownloader = pkgs.stdenv.mkDerivation rec {
    pname = "WiiUDownloader";
    version = "1.32";
    src = pkgs.fetchFromGitHub {
      owner = "Xpl0itU";
      repo = "WiiUDownloader";
      rev = "v${version}";
      fetchSubmodules = true;
      hash = "sha256-R3FiNiK27Q2x5HbHmWw3F4LPJNKz5BAoOyl4fYAEQlc=";
    };
    preConfigure = ''
      cp ${./gtitles.c} src/gtitles.c
    '';
    nativeBuildInputs = with pkgs; [
      cmake
      pkg-config
      wrapGAppsHook
    ];
    buildInputs = with pkgs; [
      curl
      mbedtls
      gtkmm3
      pcre2
      pcre-cpp
      util-linux
      libselinux
      libsepol
      libthai
      libdatrie
      xorg.libXdmcp
      libxkbcommon
      libepoxy
      xorg.libXtst
    ];

    propagatedBuildInputs = with pkgs; [
      gsettings-desktop-schemas
    ];

    installPhase = ''
      runHook preInstall
      mkdir -p $out/bin
      mv * $out/bin
      runHook postInstall
    '';
  };
in {
  services.flatpak.enable = true;
  programs.steam.enable = true;
  # Game compat
  programs.gamemode.enable = true;

  environment.systemPackages = with pkgs; [
    # For Steam
    protontricks
    
    # Minecraft
    openjdk17
    prismlauncher
    
    # PS2 Games
    pcsx2

    # Switch / WiiU Games
    cemu
    wiiUDownloader
    yuzu-early-access
    ukmm
  ];
}