final: prev: let
  config-sed = prev.buildPackages.stdenv.mkDerivation {
    name = "orc-discount-config-sed";
    src = ./config-sed.c;
    dontUnpack = true;
    buildPhase = ''
      $CC -o config.sed $src
    '';
    installPhase = ''
      mkdir -p $out/bin
      chmod +x ./config.sed
      mv config.sed $out/bin
    '';
  };
in prev.discount.overrideAttrs (old: let
  patches = [
    ./config-sed.patch
    ./make-fix.patch
  ] ++ old.patches;
  orc-tools = prev.buildPackages.stdenv.mkDerivation {
    name = "orc-discount-tools";
    src = old.src;
    inherit patches;
    configureScript = old.configureScript;
    configureFlags = old.configureFlags;
    buildPhase = ''
      $CC -o mktags mktags.c
      $CC -I ./ -o branch tools/branch.c
    '';
    installPhase = ''
      mkdir -p $out/bin
      mv mktags $out/bin
      mv branch $out/bin
    '';
  };
in {
  # ./configure does not support autoconf-style --build=/--host=.
  configurePlatforms = [ ];
  depsBuildBuild = [
    config-sed
    orc-tools
    prev.buildPackages.coreutils
  ];
  nativeBuildInputs = [
  ];
  inherit patches;
})