(final: prev: let
  noCheck = p: p.overrideAttrs (old: {
    doCheck = false;
  });
in {
  valgrind = (import ./valgrind) final prev;
  valgrind-light = final.valgrind.override { gdb = null; };
  cryptsetup = (import ./cryptsetup) final prev;
  libopus = noCheck prev.libopus;
  gn = (import ./gn) final prev;
  # Test Times out
  openexr = noCheck prev.openexr;
  ell = noCheck prev.ell;
  # Checks timeout:
  pixman = noCheck prev.pixman;
  # Inspired by: https://github.com/systemd/systemd/issues/12534
  # and https://github.com/systemd/systemd/issues/30448
  # Seems RISC-V and the like with GCC don't play well with O3
  systemd = prev.systemd.overrideAttrs (old: {
    # https://github.com/mesonbuild/meson/issues/10487
    mesonBuildType = "custom";
    mesonFlags = old.mesonFlags ++ [ "-Doptimization=2" ];
  });
  # See https://github.com/catchorg/Catch2/issues/2808
  # Fixed by https://github.com/NixOS/nixpkgs/pull/295243
  catch2_3 = prev.catch2_3.overrideAttrs (old: {
    preConfigure = (old.preConfigure or "") + ''
      export CFLAGS="$CFLAGS -Wno-error=cast-align"
    '';
  });
  # One test times out
  json-glib = noCheck prev.json-glib;
  # Openh264 doesn't support RISC-V (yet)
  # freerdp requires it by default: lets make that not true
  freerdp = prev.freerdp.override {
    openh264 = null;
  };
  tracker = noCheck prev.tracker;
  openblas = prev.openblas.overrideAttrs (old: {
    postPatch = (old.postPatch or "") + ''
      sed -i 's/-static//g' Makefile.riscv64
    '';
  });
  python3 = prev.python3.override {
    packageOverrides = final-py: prev-py: let 
      noCheck = p: p.overridePythonAttrs (old: {
       doCheck = false;
      });
    in {
      dbus-python = prev-py.dbus-python.overridePythonAttrs (old: {
        nativeBuildInputs = old.nativeBuildInputs ++ [ final.dbus ];
        doCheck = false;
      });
      hypothesis = noCheck prev-py.hypothesis;
      h2 = noCheck prev-py.h2;
      numpy = prev-py.numpy.overridePythonAttrs (old: {
        doCheck = false;
      });
      # https://github.com/pandas-dev/pandas/pull/50349 <-- This
      # but for risc-v
      pandas = noCheck prev-py.pandas;     
      sphinx = noCheck prev-py.sphinx;
      #skia-pathops = prev.skia-pathops.overridePythonAttrs (old: {
      #  patches = old.patches or [] ++ [ ./skia-riscv.patch ];
      #});
    };
  };
})