Cleanup Overlays

overlays/hydra.nix

@@ -0,0 +1,13 @@
+(final: prev: {
+  hydra_unstable = prev.hydra_unstable.overrideAttrs
+    (old: {
+      doCheck = false;
+      patches = [
+        (final.fetchpatch {
+          name = "hydra-gitea-push-patch";
+          url = "https://patch-diff.githubusercontent.com/raw/NixOS/hydra/pull/1227.patch";
+          sha256 = "A4dN/4zLMKLYaD38lu87lzAWH/3EUM7G5njx7Q4W47w=";
+        })
+      ];
+    });
+});

overlays/nvidiacontainer.nix

@@ -0,0 +1,47 @@
+(nixpkgs: (final: prev: let
+  libnvidia-container = ((
+    final.callPackage (nixpkgs+"/pkgs/applications/virtualization/libnvidia-container") { }
+  ).overrideAttrs (old: rec {
+    pname = "libnvidia-container";
+    version = "1.12.0";
+    
+    src = final.fetchFromGitHub {
+      owner = "NVIDIA";
+      repo = pname;
+      rev = "v${version}";
+      sha256 = "Ih8arSrBGGX44SiWcj61qV9z4DRrbi1J+3xxid2GupE=";
+    };
+    patches = [
+      ./libnvidia-container/inline-c-struct.patch
+      ./libnvidia-container/avoid-static-libtirpc-build.patch
+      ./libnvidia-container/libnvc-ldconfig-and-path-fix.patch
+    ];
+    postInstall =
+      let
+        inherit (final.addOpenGLRunpath) driverLink;
+        libraryPath = final.lib.makeLibraryPath [ "$out" driverLink "${driverLink}-32" ];
+      in
+        ''
+            remove-references-to -t "${final.go}" $out/lib/libnvidia-container-go.so.${version}
+            wrapProgram $out/bin/nvidia-container-cli --prefix LD_LIBRARY_PATH : ${libraryPath}
+          '';
+  }));
+in {
+  mkNvidiaContainerPkg = { name, containerRuntimePath, configTemplate, additionalPaths ? [] }:
+    let
+      nvidia-container-toolkit = final.callPackage (nixpkgs+"/pkgs/applications/virtualization/nvidia-container-toolkit") {
+        inherit containerRuntimePath configTemplate libnvidia-container;
+      };
+    in final.symlinkJoin {
+      inherit name;
+      paths = [
+        libnvidia-container
+        nvidia-container-toolkit
+      ] ++ additionalPaths;
+    };
+  nvidia-podman = final.mkNvidiaContainerPkg {
+    name = "nvidia-podman";
+    containerRuntimePath = "${final.runc}/bin/runc";
+    configTemplate = ./libnvidia-container/config.tml;
+  };
+}))