{
  description = "Build a cargo project";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    crane = {
      url = "github:ipetkov/crane";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    flake-utils.url = "github:numtide/flake-utils";

    advisory-db = {
      url = "github:rustsec/advisory-db";
      flake = false;
    };
  };

  outputs = { self, nixpkgs, crane, flake-utils, advisory-db, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs {
          inherit system;
        };

        inherit (pkgs) lib;

        craneLib = crane.lib.${system};
        src = craneLib.cleanCargoSource ./.;

        # Common arguments can be set here to avoid repeating them later
        commonArgs = {
          inherit src;

          nativeBuildInputs = with pkgs; [
            cmake
          ];
          
          buildInputs = with pkgs; [
            # Add additional build inputs here
            libopus
            stt
            tts
          ] ++ lib.optionals pkgs.stdenv.isDarwin ([
            # Additional darwin specific inputs can be set here
            pkgs.libiconv
          ] ++ (with pkgs.darwin.apple_sdk.frameworks; [
            Security
          ]));

          propagatedBuildInputs = with pkgs; [
            ffmpeg_5-headless
          ];

          meta = {
            hydraPlatforms = [ "x86_64-linux" ];
          };
          # Additional environment variables can be set directly
          # MY_CUSTOM_VAR = "some value";
        };

        # Build *just* the cargo dependencies, so we can reuse
        # all of that work (e.g. via cachix) when running in CI
        cargoArtifacts = craneLib.buildDepsOnly commonArgs;

        # Build the actual crate itself, reusing the dependency
        # artifacts from above.
        newalan = craneLib.buildPackage (commonArgs // {
          inherit cargoArtifacts;
          postInstall = ''
            mkdir -p $out/share/sounds
            cp ${./ding.mp3} $out/share/sounds/ding.mp3
          '';
        });
      in rec {
        checks = pkgs.lib.optionalAttrs (system == "x86_64-linux") {
          # Build the crate as part of `nix flake check` for convenience
          inherit newalan;

          # Run clippy (and deny all warnings) on the crate source,
          # again, resuing the dependency artifacts from above.
          #
          # Note that this is done as a separate derivation so that
          # we can block the CI if there are issues here, but not
          # prevent downstream consumers from building our crate by itself.
          newalan-clippy = craneLib.cargoClippy (commonArgs // {
            inherit cargoArtifacts;
            cargoClippyExtraArgs = "--all-targets -- --deny warnings";
          });

          newalan-doc = craneLib.cargoDoc (commonArgs // {
            inherit cargoArtifacts;
          });

          # Check formatting
          newalan-fmt = craneLib.cargoFmt {
            inherit src;
          };

          # Audit dependencies
          newalan-audit = craneLib.cargoAudit {
            inherit src advisory-db;
          };

          # Run tests with cargo-nextest
          # Consider setting `doCheck = false` on `newalan` if you do not want
          # the tests to run twice
          newalan-nextest = craneLib.cargoNextest (commonArgs // {
            inherit cargoArtifacts;
            partitions = 1;
            partitionType = "count";
          });
        } // lib.optionalAttrs (system == "x86_64-linux") {
          # NB: cargo-tarpaulin only supports x86_64 systems
          # Check code coverage (note: this will not upload coverage anywhere)
          newalan-coverage = craneLib.cargoTarpaulin (commonArgs // {
            inherit cargoArtifacts;
          });
        };
        
        hydraJobs = checks // lib.optionalAttrs
          (system == "x86_64-linux" ) {
            runCommandHook = {
              newalan = pkgs.runCommand "New Alan Deployscript" {
                nativeBuildInputs = [newalan];
              } ''
                cat << 'DOC' >> $out
#!${pkgs.runtimeShell}
export tmp=$(mktemp -d)
pushd $tmp
${pkgs.wget}/bin/wget \
  https://git.syzygial.cc/Syzygial/New-Alan/archive/${self.rev}.bundle
git clone * src
${pkgs.tree}/bin/tree
cd src
${pkgs.sops}/bin/sops -i -d secrets/config.nix
${pkgs.sops}/bin/sops -i -d secrets/deploy.sh
export flake="$tmp/src/deploy"
${pkgs.runtimeShell} ./secrets/deploy.sh
succ=$?
popd
rm -rf $tmp
if [ $succ -eq 0 ]; then
  true
else
  false
fi
DOC
                chmod +x $out
              '';
            };
          };
        
        packages.default = newalan;
        
        apps.default = flake-utils.lib.mkApp {
          drv = newalan;
        };

        devShells.default = pkgs.mkShell {
          inputsFrom = builtins.attrValues self.checks.${system};

          nativeBuildInputs = with pkgs; [
            cargo
            rustc
            rust-analyzer

            sops
            age
          ];
        };
      }
    );
}